Do you have a sound alert for MACDHistogram arrows?

Yes, alerts are very simple to add to any study. For the case you have presented. You will simply copy the code from the built in version of MACD that comes with Thinkorswim. Then add these two lines to the very bottom of that code:

Alert(UpSignal == ZeroLine, "Up Arrow Alert", Alert.BAR, Sound.RING);
Alert(DownSignal == ZeroLine, "Down Arrow Alert", Alert.BAR, Sound.RING);

THANK YOU!!!!!!! Does this script apply to any studies with arrows.

I’m not sure but its not working I have attached what I am seeing could you check it out.

Do you have a video tutorial of how to get the code from study I’m a novice at this.

Okay great I will watch the videos thanks Pete.

This the new error I’m getting.

Ok, after several failed attempts at assisting Carlos with the full implementation of this solution I decided it was time to post the full code myself. Here it is, straight from the MACD study in Thinkorswim, with only my two lines added to implement the alerts:

#
# TD Ameritrade IP Company, Inc. (c) 2007-2017
#
declare lower;
input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
input showBreakoutSignals = no;
plot Value = MovingAverage(averageType, close, fastLength) - MovingAverage(averageType, close, slowLength);
plot Avg = MovingAverage(averageType, Value, MACDLength);
plot Diff = Value - Avg;
plot ZeroLine = 0;
plot UpSignal = if Diff crosses above ZeroLine then ZeroLine else Double.NaN;
plot DownSignal = if Diff crosses below ZeroLine then ZeroLine else Double.NaN;
UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);
Value.SetDefaultColor(GetColor(1));
Avg.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.color("Positive and Up") else Diff.color("Positive and Down") else if Diff < Diff[1] then Diff.color("Negative and Down") else Diff.color("Negative and Up"));
ZeroLine.SetDefaultColor(GetColor(0));
UpSignal.SetDefaultColor(Color.UPTICK);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
Alert(UpSignal == ZeroLine, "Up Arrow Alert", Alert.BAR, Sound.RING);
Alert(DownSignal == ZeroLine, "Down Arrow Alert", Alert.BAR, Sound.RING);