Finding a Macd Crossover below the zero line

In response to question from Yvens Junior Ulysse

can this be made into a scanner? been trying and couldnt get it to work

Yes, and instead of just giving you the code I will try to explain the process so you can apply this method to other studies.

You see in the code there are 6 statements that begin with the word “plot”. A scan will only permit a single “plot” statement. Start at the top of the code, and change the first four “plot” to “def”. So we convert the first four to “def” because we still need those values. Once you do this, you will notice several statements immediately below these that turn red. Those are style statements for the plots. We changed them from “plot” to “def” so they will not accept style statements. We simply delete those lines. All the way from Value.SetDefaultColor(GetColor(1)); down to ZeroLine.SetDefaultColor(GetColor(0));

Next, we need to get rid of the two plot statements at the bottom. Likewise, each of these are followed by style statements. Once you delete the last two plot statements those style statements will turn red and need to be deleted.

So having followed these steps the last two lines of code should be:

def ValueCrossBelowZeroline = Value[1] < Avg[1] and Value[1] < 0 and Value > Avg;
def ValueCrossAboveZeroline = Value[1] > Avg[1] and Value[1] > 0 and Value < Avg;

These are the signals we’ll use in the scan.

If you want to scan for both conditions at the same time you will use:

plot scan = ValueCrossBelowZeroline or ValueCrossAboveZeroline;

And if you want to scan for each signal separately you will use one of the following:

plot scan = ValueCrossBelowZeroline;

or

plot scan = ValueCrossAboveZeroline;

Don’t worry if it doesn’t work out the first time. If you don’t get a working scan the first time through, don’t try and patch it together. Just erase all the code and start over from the beginning.

Hope it helps.

In response to the original question from Obelix Gaulois

Yes and this is pretty simple. You didn’t provide a link or the name of which video you are referring too so I’ll just post a couple lines of code that will express the conditions specified in your question.

Before we get into that. You asked if it were possible to tell “how deep is the crossover below the zero line”. Very important to note that MACD does not have true “overbought/oversold” levels. The amount the lines move above or below zero is directly related to price of the underlying instrument. A 5 dollar stock will have a much lower range above and below zero then a 500 dollar stock. So, we’ll just skip that request in our solution. I suggest you combine this with an RSI or a Stochastic if you want to cover the overbought/oversold conditions.

Ok, so let’s get to the code:

This is taken from a standard MACD so we have the same inputs and variable names. Screenshot attached.

declare lower;
input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
plot Value = MovingAverage(averageType, close, fastLength) - MovingAverage(averageType, close, slowLength);
plot Avg = MovingAverage(averageType, Value, MACDLength);
plot Diff = Value - Avg;
plot ZeroLine = 0;
Value.SetDefaultColor(GetColor(1));
Avg.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor("Positive and Up", Color.GREEN);
Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.color("Positive and Up") else Diff.color("Positive and Down") else if Diff < Diff[1] then Diff.color("Negative and Down") else Diff.color("Negative and Up"));
ZeroLine.SetDefaultColor(GetColor(0));


# now for the signal
def ValueCrossBelowZeroline = Value[1] < Avg[1] and Value[1] < 0 and Value > Avg;
plot belowZeroCross = if ValueCrossBelowZeroline then Value else Double.NaN;
belowZeroCross.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
belowZeroCross.SetDefaultColor(Color.CYAN);
def ValueCrossAboveZeroline = Value[1] > Avg[1] and Value[1] > 0 and Value < Avg;
plot aboveZeroCross = if ValueCrossAboveZeroline then Value else Double.NaN;
aboveZeroCross.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
aboveZeroCross.SetDefaultColor(Color.MAGENTA);

Hi Pete,

Sorry for the late reply. I really appreciate the prompt reply. I haven’t had the chance to play with the answer you posted but I’m sure I will be able to transform it into a TOS scan which I was looking for.  I now have an indicator and I can try to turn in into a scan. After I do, I can post a follow up. Thanks again Pete.

can this be made into a scanner? been trying and couldnt get it to work

wow! i wasn’t expecting you to reply so quickly, especially over the weekend. thanks! it works. Can the same be done for bearish percentDLength percentKLength crosses above 40 and bullish percentDLength percentKLength crosses below -40 for stochastic momentum index indicator? fought with it for a while and clearly didnt win haha (i’m new at this).

peter, thank you for these great tutorials!! In regards to this scan is it possible to put a code in that this happened “Within” a certain period? I attempted to add “within 3 bars;” but it did not like that code.

Hello Pete,

While searching through the forum, I found exactly what I was looking for.  However, I think there is something wrong with my computer (a Mac Mini) or the TOS scanner.  I included a screenshot of my scan results and it is indicating that out of 521 stocks, 498 meet this scan criteria and I seriously doubt that.  The scan (Bobs_MACD_Scan) I’m using is the one you have posted and I have included it below.  The strange thing is that any new scan I create comes up with the same results.  If I use older and different kinds of  scans, they work perfectly.  I closed TOS and deleted the ‘User GUI’ file and loaded TOS back up so I am running the current software.  When you run this scan, what kind of results are you receiving?

declare lower;
input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
plot Value = MovingAverage(averageType, close, fastLength) – MovingAverage(averageType, close, slowLength);
plot Avg = MovingAverage(averageType, Value, MACDLength);
plot Diff = Value – Avg;
plot ZeroLine = 0;
Value.SetDefaultColor(GetColor(1));
Avg.SetDefaultColor(GetColor(8));
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(3);
Diff.DefineColor(“Positive and Up”, Color.GREEN);
Diff.DefineColor(“Positive and Down”, Color.DARK_GREEN);
Diff.DefineColor(“Negative and Down”, Color.RED);
Diff.DefineColor(“Negative and Up”, Color.DARK_RED);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.color(“Positive and Up”) else Diff.color(“Positive and Down”) else if Diff < Diff[1] then Diff.color(“Negative and Down”) else Diff.color(“Negative and Up”));
ZeroLine.SetDefaultColor(GetColor(0));

# now for the signal
def ValueCrossBelowZeroline = Value[1] < Avg[1] and Value[1] < 0 and Value > Avg;
plot belowZeroCross = if ValueCrossBelowZeroline then Value else Double.NaN;
belowZeroCross.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
belowZeroCross.SetDefaultColor(Color.CYAN);
def ValueCrossAboveZeroline = Value[1] > Avg[1] and Value[1] > 0 and Value < Avg;
plot aboveZeroCross = if ValueCrossAboveZeroline then Value else Double.NaN;
aboveZeroCross.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
aboveZeroCross.SetDefaultColor(Color.MAGENTA);

plot scan = ValueCrossBelowZeroline;

Thanks for your input Pete as I now have the scan working correctly.