PPO column based on conditional values

Whenever you are working with custom chart studies it's important that you NOT try to reference the custom study in your code. Meaning that its best if you avoid using the Condition Wizard to build your solution. Why? It has been observed that referencing a custom study in the Condition Wizard has been shown to produce unreliable results in the past. It may work in most cases, but not all. So the safest thing is to always use the entire code in your solutions when a custom study is involved.

For this solution I have embedded your code within a script structure. This allows us to reference the same set of computations multiple times while using a different set of inputs in each instance. This saves a lot of space and makes the code much easier to read and maintain. If you have not worked with script structures in Thinkorswim before I suggest you read up on them here:

https://toslc.thinkorswim.com/center/reference/thinkScript/Reserved-Words/script

Here is the code that you can drop into a custom watchlist column to produce the output you specified:

script myPPO {
input fastPeriod = 8;
input slowPeriod = 17;
input signalPeriod = 9;
input price = close;
def fastEma = ExpAverage(price, fastPeriod);
def slowEma = ExpAverage(price, slowPeriod);
def periodOK = fastPeriod < slowPeriod;
plot ppo = if periodOK then (((fastEma – slowEma) / slowEma) * 100) else 0;
}
# ppoenhanced(“fast period” = 1, “slow period” = 5, “signal period” = 1).”PPO” is greater than 0;
def conditionOne = if myPPO(1, 5, 1) > 0 then 900 else 0;
# ppoenhanced(“fast period” = 5, “slow period” = 13, “signal period” = 1).”PPO” is greater than 0;
def conditionTwo = if myPPO(5, 13, 1) > 0 then 90 else 0;
# ppoenhanced(“fast period” = 21, “slow period” = 34, “signal period” = 1).”PPO” is greater than 0;
def conditionThree = if myPPO(21, 34, 1) > 0 then 9 else 0;
plot data = conditionOne + conditionTwo + conditionThree;

One final note about this solution. I have included your original conditions as comment lines in this code. This will help you match your original conditions to the new code structure I created to plot the values as you specified.

Edit: I thought it would be helpful to convert this code to plot as a lower study with a chart label displaying the same value as the watchlist column. The following code displays three plots on the lower sub-graph. I have not included any styles for the plot statements so you can adjust them however you like. I personally found that histogram style makes things pretty clear.

declare lower;
script myPPO {
input fastPeriod = 8;
input slowPeriod = 17;
input signalPeriod = 9;
input price = close;
def fastEma = ExpAverage(price, fastPeriod);
def slowEma = ExpAverage(price, slowPeriod);
def periodOK = fastPeriod < slowPeriod;
plot ppo = if periodOK then (((fastEma – slowEma) / slowEma) * 100) else 0;
}
def conditionOne = if myPPO(1, 5, 1) > 0 then 900 else 0;
def conditionTwo = if myPPO(5, 13, 1) > 0 then 90 else 0;
def conditionThree = if myPPO(21, 34, 1) > 0 then 9 else 0;
def data = conditionOne + conditionTwo + conditionThree;
AddLabel(yes, "PPO Condition: " + data, Color.WHITE);
plot ppoOne = myPPO(1, 5, 1);
plot ppoTwo = myPPO(5, 13, 1);
plot ppoThree = myPPO(21, 34, 1);