Pulls back to the 21 EMA or 50 EMA?

So you actually have a lot going on there. You have defined an uptrend and a downtrend. For each trend direction you have defined two separate patterns. Which involves the 21 and the 50 exponential moving averages. I see you also mention hooking up from 20 and hooking down from 80. I am guessing those are for the Stochastic although you don’t specifically mention that. I’ll consider your previous post in which we cover the Stochastic portion: https://www.hahn-tech.com/ans/alert-fullk-crosses-fulld-overbought/

So excluding the Stochastic I have the following code for you. I’ve broken down all the elements into separate lines so you can follow the logic. The last four lines are your signals. I did not provide any plots, leaving it to you to work out how you want to use the last four signals in whatever method you choose. I have not tested this so there may be some errors. Let me know how it works and I’ll make any adjustments needed to get things dialed in.

def ema1 = ExpAverage(close, 21);
def ema2 = ExpAverage(close, 50);
def sma1 = Average(close, 200);
def uptrend = close > sma1;
def downtrend = close < sma1; def pullBackEMA1 = close[1] > ema1[1] and close < ema1; def pullBackEMA2 = close[1] > ema2[1] and close < ema2;
def rallyToEMA1 = close[1] < ema1[1] and close > ema1;
def rallyToEMA2 = close[1] < ema2[1] and close > ema2;
def pullBack1 = uptrend and pullBackEMA1;
def pullBack2 = uptrend and pullBackEMA2;
def rallyBack1 = downtrend and rallyToEMA1;
def rallyBack2 = downtrend and rallyToEMA2;

Hi Pete,

When I do this to the last 4 lines:

Plot pullBack1 = uptrend and pullBackEMA1;
Plot pullBack2 = uptrend and pullBackEMA2;
#Plot rallyBack1 = downtrend and rallyToEMA1;
#Plot rallyBack2 = downtrend and rallyToEMA2;

Why does it give an error: “Exactly one plot expected”?

Hi Pete,

I used the “Plot scan” above and it gave attached error (it did not allow me to copy the error in Scan). Please see attached file.

Thanks.

I don’t think the logic is working. Please see attached file. Though price gets near EMAs, it’s not hooking up from 20, but it already gives scan result. Please check. Thanks.

Please see attached screen shot. Scan gives this as a Sell signal. However, price is above EMAs and not even pulls back and it hooks down from 80. Price supposed to rally up if it’s a sell hooking down. Logic is not working somehow.

Please show how to fix. Thanks

Please see attached file. Scan gives as a Buy. Though hooks up from 20, price not even pullback near EMAs yet. It gives signal too soon.

Thanks.

See attached file. Scan gives as a Sell. However, price still above EMAs (even above 200). Logic is not working.

Thanks.

Please see attached file. Scan gives signal as a buy. However, price still above EMAs, even though it’s hooking down from 80.

Ok, I regret that this post has dragged on for so long without coming to a conclusion. I had expected that the code I had provided was clear and concise enough that it could be easily understood and flexible enough for viewers to apply as they saw fit. I was incorrect, and I apologize. So here is the code and associated screenshot. This code combines the Stochastic “hooks” as well as the price pullbacks and rallies to the key moving averages of 21 EMA and 50 EMA. The 200 SMA is used as the trend direction. This code includes the elements from the Stochastic and everything is combined into a single cohesive program. There are two modes for this scan. One finds potential long signals while the other finds potential short signals. You cannot run them both together. The signals you are searching for almost never occurr at the same time. So the pullback to the EMA has to occur first, followed by the Stochastic “hook”. To accomplish this I have included 5 bars of space for both conditions to have occurred. The screenshot shows three charts, each were picked up in a current scan using daily time frame. In each chart you can see the pullback to a key EMA has occurred several bars prior to the Stochastic “hook”. Having provided this solution I am closing this topic so as to avoid any further confusion for future visitors to this post.


input over_bought = 80;
input over_sold = 20;
input KPeriod = 10;
input DPeriod = 10;
input priceH = high;
input priceL = low;
input priceC = close;
input slowing_period = 3;
input averageType = AverageType.SIMPLE;
def lowest_k = Lowest(priceL, KPeriod);
def c1 = priceC - lowest_k;
def c2 = Highest(priceH, KPeriod) - lowest_k;
def FastK = if c2 != 0 then c1 / c2 * 100 else 0;
def FullK = MovingAverage(averageType, FastK, slowing_period);
def FullD = MovingAverage(averageType, FullK, DPeriod);
def fullKCrossesFromOverbought = FullK[1] > 80 and FullK < 80; def fullKCrossesBelowFullD = FullK[1] > FullD[1] and FullK < FullD;
def stochasticSell = fullKCrossesFromOverbought and fullKCrossesBelowFullD;
def fullKCrossesFromOversold = FullK[1] < 20 and FullK > 20;
def fullKCrossesAboveFullD = FullK[1] < FullD[1] and FullK > FullD;
def stochasticBuy = fullKCrossesFromOversold and fullKCrossesAboveFullD;
def ema1 = ExpAverage(close, 21);
def ema2 = ExpAverage(close, 50);
def sma1 = Average(close, 200);
def uptrend = close > sma1;
def downtrend = close < sma1; def pullBackEMA1 = close[1] > ema1[1] and close < ema1; def pullBackEMA2 = close[1] > ema2[1] and close < ema2;
def rallyToEMA1 = close[1] < ema1[1] and close > ema1;
def rallyToEMA2 = close[1] < ema2[1] and close > ema2;
def pullBack1 = uptrend and pullBackEMA1;
def pullBack2 = uptrend and pullBackEMA2;
def rallyBack1 = downtrend and rallyToEMA1;
def rallyBack2 = downtrend and rallyToEMA2;
# use this scan to seach for long entry signals
plot scan = stochasticBuy and (pullBack1 or pullBack2) within 5 bars;
# use this scan to search for short entry signals
#plot scan = stochasticSell and (rallyBack1 or rallyBack2) within 5 bars;