Scan for stocks trending downward

I am going to take a bit more time on this post. I want to review the code presented by the author to explain exactly what the code does. This will enable us to compare that to requested specifications. This is not intended to point out flaws, this is intended to provide education.

Here is the author’s original code:

input n = 5;
input nn = 5;
def a = if open < open[1] then 1 else 0;
plot b = if sum(a,n) >= nn then 1 else 0;

User Inputs

There are two user inputs, (n and nn). Their default values are set to 5. I am not a fan of excessive abbreviations in code. Those variable names should describe exactly what they are. Abbreviations make code less readable. Use them sparingly.

Check for Lower Open

After the two user inputs we have another variable, (a). We don’t have the slightest clue what is intended here because it’s just a single letter. This is not even an abbreviation. But we can read the code and we find this variable named “a” is set to a value of 1 if the open of the current bar is less than the open of the previous bar. If not, this variable is set to 0. This is how the line of code should be written:

def lowerOpen = open < open[1];

In place of a single letter we have a variable name which describes exactly what that variable contains. And if you are setting value of 1 or 0, there is no need for the if-then-else statement. In this case the expression that compares the current open to the previous open evaluates to true or false. In Thinkorswim the true/false values are actually numeric. True is always 1 and false is always 0. So we don’t need to assign them using the if-then-else.

Series of Consecutive Lower Opens

Ok, this brings us to the final line of code. Once again we have a single letter variable name. We don’t have the slightest clue what was intended here. So we have to read the code. The code is using the Sum() method and is calculating the sum of the “a” variable over the last “n” bars. It then takes this value and checks if it is greater than or equal to the “nn” input. Using the default inputs, this code basically says this: “check if the current bar’s open is less than the previous bar’s open for every one of the previous 5 or more bars.”

Properly Structured Code

So this is what this the entire code should look like, when written properly:

input lookBackBars = 5;
input minimumSeries = 5;
def lowerOpen = open < open[1];
plot seriesOfLowerOpens = Sum(lowerOpen, lookBackBars) >= minimumSeries;

Much easier to read. Still doesn’t even come close to meeting the specifications. But at least this code can be read and understood very quickly. This code is not “a bit inefficient”. And it does not “at times returned undesirable results”. This code always misses the mark, 100% of the time. Because it does not contain any of the elements from the stated specification. Not a single element. It’s very important you understand this, if you have a desire to learn how to do this.

The Solution

The way the specifications are structured leaves room for more than one interpretation. So we have to make some assumptions. The first specification is for the 5 period sma trending down.

One way to interpret that statement is to simply compare the current value of the 5 period sma to its value from 3 bars ago. Another way to interpret this is to say the 5 period sma must be lower than it’s previous value for 3 consecutive bars. We’ll be applying the first interpretation here.

Likewise, we can interpret the second specification in one of these two ways. Once again, we’ll be applying the first interpretation, because it’s easier.

The Final Code

input length = 5;
input percent = 5.0;
def sma = Average(close, length);
def smaTrendingDown = sma < sma[3];
def lowerHighByPercent = high < (high[3] * (1 - percent * 0.01));
def downBar = close < open;
def threeConsecutiveDownBars = Lowest(downBar, 3) > 0;
plot scan = smaTrendingDown and lowerHighByPercent and threeConsecutiveDownBars;

Review

Notice the final line of the code is the scan plot. You will see it contains our three specifications, spelled out clearly because we didn’t use excessive abbreviations when naming our variables.

Using the default inputs here I would expect this to be exceptionally rare. This is due to the percent being applied to the high from 3 bars ago. When are you going to find a case where you to see a 5% decline in price within 15 minutes? Which is 3 bars on a 5 minute time frame. Only on the opening bar, during a severe gap down from the previous close.

So you should start with a very, very small percent value. Perhaps something like 0.1. Or take some time to examine these patterns you are trying to pick up and calculate the average percent move that actually occurs in 3 bars.

Screenshot

Attached is a screenshot showing what this looks like using a percent value of 0.1, as applied to a Study Alert. You can see the spikes in the lower subgraph indicating when the conditions are true.