stop plots from continuing after last bar

First, a quick lesson on posting in a forum. When you enter a title for your question, consider it like the subject line of an email. It should be brief. Between 6-8 words. At the same time it should clearly describe the context of your question. Here is the title you entered:

strange result of a volume type script I wrote, I'm wondering if you can see the cause, it

From the details you included I see you have a plot that repeats the value of the last bar into the right expansion area of the chart. Given this context, I have changed the title of this post so other viewers seeking a similar solution are able to search for and find it.

Now, on to the solution. I found the following lines of code that may cause this problem:

def Buying = if (isNan(isBuyNan), Buying[1],Round(V*(C-L)/(H-L)));
def Selling = if (isNan(isSellNan), Selling[1],Round( V*(H-C)/(H-L)));

Both lines of code are doing the same thing for opposite sides of your study. So let's just examine the first line, the second line will be resolved in a similar fashion. I see that you are using a test for NaN: IsNaN(isBuyNan)

And when the value of isBuyNan is not a number (NaN), then you recursively capture the previous bar's value for the variable named Buying. Every column on the chart where bars are present, isBuyNan will be a number.

So where on the chart do we find that isBuyNan is equal to NaN? For every column AFTER the last bar on the chart, isBuyNan will equal NaN. The net result of this is that your code is purposely repeating the value from the last bar on the chart into those columns on the right where isBuyNan is equal to NaN.

This gives us the solution to your problem:

def Buying = Round(V * (C - L) / (H - L));

Just apply a similar fix to the Selling variable.

Last note, there was a typo in your code. The plot names do not match the style names. As shown here:

# Selling Volume
Plot SellVol = Selling;
SV.setPaintingStrategy(PaintingStrategy.Histogram);
SV.SetDefaultColor(Color.downtick);
SV.HideTitle();
SV.HideBubble();
SV.SetLineWeight(4);

# Buying Volume
# Note that Selling + Buying Volume will equal Volume.
Plot BuyVol = Buying;
BV.setPaintingStrategy(PaintingStrategy.Histogram);
BV.SetDefaultColor(Color.uptick);
BV.HideTitle();
BV.HideBubble();
BV.SetLineWeight(4);

This needs to be corrected because it creates an error and the code cannot be applied to the chart until it is fixed. As shown here:

# Selling Volume
Plot SellVol = Selling;
SellVol.setPaintingStrategy(PaintingStrategy.Histogram);
SellVol.SetDefaultColor(Color.downtick);
SellVol.HideTitle();
SellVol.HideBubble();
SellVol.SetLineWeight(4);

# Buying Volume
# Note that Selling + Buying Volume will equal Volume.
Plot BuyVol = Buying;
BuyVol.setPaintingStrategy(PaintingStrategy.Histogram);
BuyVol.SetDefaultColor(Color.uptick);
BuyVol.HideTitle();
BuyVol.HideBubble();
BuyVol.SetLineWeight(4);