Volume per candle

The only way to display the data for a candle you are hovering over with the mouse, is to use a plot statement. It is not possible to display that value in a chart label. Because thinkscript has no interface to enable the code to “see” what the user is pointing to with the mouse.

My second answer is in response to an additional question asked by Ryan in the comments section of my last email.

On 4/24/18 Ryan asked:

I would like to have the Daily Average set to the average over the last 252 days. Currently this only shows when I have the length input to 252 and on a daily time frame. How can I keep this true if I use any other time frame? What code should I put in place of this?

Here is the entire text of Ryan’s code:

#FibKing Creations
#FibKing Trading
#www.FibKingTrading.com
#Volume Stats
#Updated 4.24.18
#Inputs
input length = 252;
input avglength = 30;
input ShowDailyAvg = yes;
input ShowTodayVolume = yes;
input ShowPercentOfDayAvg = yes;
input UnusualVolumePercent = 100;
input ShowBarAvg = yes;
input ShowCurrentBar = yes;
#Volume Data Defined
def volYearDayAvg = Average(volume, length);
def today = volume(period = "DAY");
def percentOfDay = Round((today / volYearDayAvg) * 100, 0);
def avglengthBars = Average(volume, avglength);
def percentOfAvg = Round((today / avglengthBars) * 100, 0);
def curVolume = volume;
#Labels
AddLabel(ShowDailyAvg, "Daily Avg: " + Round(volYearDayAvg, 0), Color.LIGHT_GRAY);
AddLabel(ShowPercentOfDayAvg, percentOfDay + "%", (if percentOfDay >= UnusualVolumePercent then Color.GREEN else if percentOfDay >= 100 then Color.ORANGE else Color.WHITE) );
AddLabel(ShowTodayVolume, "Today: " + today, (if percentOfDay >= UnusualVolumePercent then Color.GREEN else if percentOfDay >= 100 then Color.ORANGE else Color.LIGHT_GRAY));
AddLabel(ShowBarAvg, "Avg Bars: " + Round(avglengthBars, 0), Color.LIGHT_GRAY);
AddLabel(ShowPercentOfDayAvg, percentOfAvg + "%", (if percentOfAvg >= UnusualVolumePercent then Color.GREEN else if percentOfAvg >= 100 then Color.ORANGE else Color.WHITE) );
AddLabel(ShowCurrentBar, "Cur Bar: " + curVolume, (if curVolume >= avglengthBars then Color.GREEN else Color.ORANGE));
#High Volume dot
def aVol = Average(volume, avglength);
def pVol = 100 * ((volume - aVol[1]) / aVol[1]);
def pDot = pVol >= unusualVolumePercent;
plot volumeStrength = if pDot then hl2 else Double.NaN;
volumeStrength.SetPaintingStrategy(PaintingStrategy.boolEAN_POINTS);
volumeStrength.SetLineWeight(5);
volumeStrength.SetDefaultColor(Color.white);
volumeStrength.HideBubble();
#Alerts
input enableAlerts = Yes;
alert(enableAlerts and pDot, "Volume Strength Alert", alert.bar, sound.ring);

His year-long daily average is computed on this line:

def volYearDayAvg = Average(volume, length);

In order to force this to read from the daily time frame when the chart is set to a LOWER time frame you will modify that line of code to this:

def volYearDayAvg = Average(volume(period = AggregationPeriod.DAY), length);

Give it a try and let us know how it goes. (this will cause an error when plotted on a time frame higher than daily)